Nigel & Grant:
I also have a script. Mine assumes that each sub has a WCS on it; a local install of astrometry.net does the job. The script then takes two parameters --- the movement in RA and Dec in arcsec/hour --- and a list of images. The images then have their WCS modified to reflect the movement after the earliest taken image.
The result can then be stacked anyway you like, with your usual tools. I use SWarp.
My Perl script has 60 lines, including comments and white space layout. Here it is in case anyone else can make use of it.
8<---------------------------------------------------------------------------------->8
#! /usr/bin/perl
use strict;
use warnings;
sub gregorian2jd ($$$) # Convert Year/Month/Day to Julian Day number.
{ # Algorithm from Wikipedia.
my ($y, $m, $d) = @_;
use integer;
return (1461 * ($y + 4800 + ($m - 14)/12))/4 + # All of this
(367 * ($m - 2 - 12 * (($m - 14)/12)))/12 - # is very
(3 + (($y + 4900 + ($m - 14)/12)/100))/4 + # deep magic.
$d -
32075;
}
scalar @ARGV < 3 and die "Not enough arguments\n";
my %file_times = (); # Time of observation for each file.
my %file_RA = (); # RA of reference point for each file.
my %file_Dec = (); # Dec of reference point for each file.
my $deltaRA = shift;
$deltaRA =~ /^[-+]?\d+\.\d+$/ or die "Funny sky deltaRA $deltaRA\n";
$deltaRA /= 3600 * 3600; # Convert arcsec/hour to degrees/second.
my $deltaDec = shift;
$deltaDec =~ /^[-+]?\d+\.\d+$/ or die "Funny sky deltaDec $deltaDec\n";
$deltaDec /= 3600 * 3600;
my $start = 1e20; # Way in the future.
undef $/; # Slurp.
foreach my $file (@ARGV) { # First pass, read times & coordinates of reference point.
open FITS, "< $file" or die "Can't read $file\n";
my $data = <FITS>;
close FITS;
my ($year, $month, $day, $hour, $minute, $second) =
$data =~ /DATE-OBS= '(\d\d\d\d)-(\d\d)-(\d\d)T(\d\d):(\d\d):(\d\d)/; # Second resolution good enough.
if ($year) { # Co-added files generally don't have a DATE-OBS card.
my $time = gregorian2jd ($year, $month, $day)*24*60*60 + $hour*60*60 + $minute*60 + $second;
$file_times{$file} = $time;
$start = $time if $start > $time; # Record earliest observation.
($file_RA{$file}) = $data =~ /CRVAL1\s+=\s+(\S+)/;
($file_Dec{$file}) = $data =~ /CRVAL2\s+=\s+(\S+)/;
}
}
foreach my $file (keys %file_times) { # Second pass: move the reference point for each image.
open FITS, "< $file" or die "Can't read $file\n";
my $data = <FITS>;
close FITS;
my $deltat = $file_times{$file} - $start;
my $newRA = $file_RA{$file} - $deltaRA * $deltat;
my $newDec = $file_Dec{$file} - $deltaDec * $deltat;
$data =~ s/(CRVAL1\s+=\s)(\s*)(\S+)/sprintf ("%s%20.9f", $1, $newRA)/e;
$data =~ s/(CRVAL2\s+=\s)(\s*)(\S+)/sprintf ("%s%20.9f", $1, $newDec)/e;
open FITS, "> new_$file" or die "Can't write new_$file\n";
printf FITS "%s", $data;
close FITS
}
# That's all folks!
